feat(config): fish configs

config/fish/conf.d/_tide_init.fish

@@ -0,0 +1,44 @@
+function _tide_init_install --on-event _tide_init_install
+    set -U VIRTUAL_ENV_DISABLE_PROMPT true
+
+    source (functions --details _tide_sub_configure)
+    _load_config lean
+    _tide_finish
+
+    if status is-interactive
+        tide bug-report --check || sleep 4
+
+        if contains ilancosman/tide (string lower $_fisher_plugins)
+            set_color bryellow
+            echo "ilancosman/tide is a development branch. Please install from a release tag:"
+            _tide_fish_colorize "fisher install ilancosman/tide@v6"
+            sleep 3
+        end
+
+        switch (read --prompt-str="Configure tide prompt? [Y/n] " | string lower)
+            case y ye yes ''
+                tide configure
+            case '*'
+                echo -s \n 'Run ' (_tide_fish_colorize "tide configure") ' to customize your prompt.'
+        end
+    end
+end
+
+function _tide_init_update --on-event _tide_init_update
+    # Warn users who install from main branch
+    if contains ilancosman/tide (string lower $_fisher_plugins)
+        set_color bryellow
+        echo "ilancosman/tide is a development branch. Please install from a release tag:"
+        _tide_fish_colorize "fisher install ilancosman/tide@v6"
+        sleep 3
+    end
+
+    # Set (disable) the new jobs variable
+    set -q tide_jobs_number_threshold || set -U tide_jobs_number_threshold 1000
+end
+
+function _tide_init_uninstall --on-event _tide_init_uninstall
+    set -e VIRTUAL_ENV_DISABLE_PROMPT
+    set -e (set -U --names | string match --entire -r '^_?tide')
+    functions --erase (functions --all | string match --entire -r '^_?tide')
+end

config/fish/conf.d/fish-ssh-agent.fish

@@ -0,0 +1,7 @@
+if test -z "$SSH_ENV"
+    set -xg SSH_ENV $HOME/.ssh/environment
+end
+
+if not __ssh_agent_is_started
+    __ssh_agent_start
+end

config/fish/conf.d/halostatue_fish_brew.fish

@@ -0,0 +1,62 @@
+# @halostatue/fish-brew/conf.d/halostatue_fish_brew.fish:v3.2.1
+
+# Find Homebrew via a known prefix. If the `__homebrew_prefix` universal
+# variable is set, that will be set as the first test prefix.
+if not command --query brew
+    set --local prefixes $HOME/.brew $HOME/.linuxbrew /opt/homebrew /usr/local
+    set --query --universal __homebrew_prefix
+    and set --prepend prefixes $__homebrew_prefix
+
+    for prefix in $prefixes
+        test -x $prefix/bin/brew
+        or continue
+
+        set --prepend PATH $prefix/bin
+        break
+    end
+end
+
+if command --query brew
+    set --query --universal __brew_prefix
+    and set --erase --universal __brew_prefix
+
+    set --local __brew_prefix (brew --prefix)
+
+    if ! contains -- {$__brew_prefix}/bin $fish_user_paths
+        fish_add_path --append --move --path \
+            {$__brew_prefix}/bin \
+            /usr/local/bin \
+            /usr/bin \
+            /bin \
+            {$__brew_prefix}/sbin \
+            /usr/local/sbin \
+            /usr/sbin \
+            /sbin
+    end
+
+    if test -s $HOME/.config/brew/config.fish
+        if status is-interactive
+            set --local deprecated 0
+
+            if set --query $__halostatue_fish_brew_config_deprecated
+                set deprecated $__halostatue_fish_brew_config_deprecated
+            end
+
+            if test $deprecated -le 0
+                echo >&2 "Sourcing ~/.config/brew/config.fish is deprecated."
+                echo >&2 "See https://docs.brew.sh/Manpage#environment for a better alternative."
+
+                set --universal $__halostatue_fish_brew_config_deprecated 10
+            else
+                set --universal $__halostatue_fish_brew_config_deprecated (math $deprecated - 1)
+            end
+        end
+
+        source $HOME/.config/brew/config.fish
+    end
+end
+
+function _halostatue_fish_brew_uninstall -e halostatue_fish_brew_uninstall
+    set --universal --erase __brew_prefix __halostatue_fish_brew_config_deprecated
+    functions --erase has_cask has_keg (status function)
+end

config/fish/conf.d/halostatue_fish_macos.fish

@@ -0,0 +1,14 @@
+# @halostatue/fish-macos/conf.d/halostatue_fish_macos.fish:v7.0.0
+
+function _halostatue_fish_macos_uninstall -e halostatue_fish_macos_uninstall
+    set --function functions app finder has_app mac manp note ql remind
+
+    for cmd in $functions
+        complete --erase --command $cmd
+    end
+
+    set --append functions (status function) \
+        (functions --all | string match --entire --regex '^__macos_app_|^__macos_finder_|^__macos_mac_')
+
+    functions --erase $functions
+end

config/fish/conf.d/nvm.fish

@@ -0,0 +1,28 @@
+set --query XDG_DATA_HOME || set --local XDG_DATA_HOME ~/.local/share
+set --query nvm_mirror || set --global nvm_mirror https://nodejs.org/dist
+set --query nvm_data || set --global nvm_data $XDG_DATA_HOME/nvm
+
+function _nvm_install --on-event nvm_install
+    test ! -d $nvm_data && command mkdir -p $nvm_data
+    echo "Downloading the Node distribution index..." 2>/dev/null
+    _nvm_index_update
+end
+
+function _nvm_update --on-event nvm_update
+    set --query --universal nvm_data && set --erase --universal nvm_data
+    set --query --universal nvm_mirror && set --erase --universal nvm_mirror
+    set --query nvm_mirror || set --global nvm_mirror https://nodejs.org/dist
+end
+
+function _nvm_uninstall --on-event nvm_uninstall
+    command rm -rf $nvm_data
+
+    set --query nvm_current_version && _nvm_version_deactivate $nvm_current_version
+
+    set --names | string replace --filter --regex -- "^nvm" "set --erase nvm" | source
+    functions --erase (functions --all | string match --entire --regex -- "^_nvm_")
+end
+
+if status is-interactive && set --query nvm_default_version && ! set --query nvm_current_version
+    nvm use --silent $nvm_default_version
+end

config/fish/conf.d/paths.fish

@@ -0,0 +1,22 @@
+function ___paths_plugin_set_colors
+    if not set -q ___paths_plugin_colors
+        set -Ux ___paths_plugin_colors 27e6ff 29e0ff 5cd8ff 77d0ff 8ac8ff 9cbfff afb5ff c5a7ff d99bfe ea8feb f684d5 fe7abd ff73a3 ff708a fa7070 ff708a ff73a3 fe7abd f684d5 ea8feb d99bfe c5a7ff afb5ff 9cbfff 8ac8ff 77d0ff 5cd8ff 29e0ff
+    end
+    return 0
+end
+
+function _paths_uninstall --on-event paths_uninstall
+    for i in ___paths_plugin_wrap_color ___paths_plugin_output ___paths_plugin_handle_found_item ___paths_plugin_handle_source ___paths_plugin_cycle_color
+        functions -e $i
+    end
+    set -e ___paths_plugin_colors
+    set -e ___paths_plugin_current_color
+end
+
+function _paths_install --on-event _paths_install
+    ___paths_plugin_set_colors
+end
+
+function _paths_update --on-event paths_update
+    ___paths_plugin_set_colors
+end

config/fish/conf.d/z.fish

@@ -0,0 +1,63 @@
+if test -z "$Z_DATA"
+    if test -z "$XDG_DATA_HOME"
+        set -U Z_DATA_DIR "$HOME/.local/share/z"
+    else
+        set -U Z_DATA_DIR "$XDG_DATA_HOME/z"
+    end
+    set -U Z_DATA "$Z_DATA_DIR/data"
+end
+
+if test ! -e "$Z_DATA"
+    if test ! -e "$Z_DATA_DIR"
+        mkdir -p -m 700 "$Z_DATA_DIR"
+    end
+    touch "$Z_DATA"
+end
+
+if test -z "$Z_CMD"
+    set -U Z_CMD z
+end
+
+set -U ZO_CMD "$Z_CMD"o
+
+if test ! -z $Z_CMD
+    function $Z_CMD -d "jump around"
+        __z $argv
+    end
+end
+
+if test ! -z $ZO_CMD
+    function $ZO_CMD -d "open target dir"
+        __z -d $argv
+    end
+end
+
+if not set -q Z_EXCLUDE
+    set -U Z_EXCLUDE "^$HOME\$"
+else if contains $HOME $Z_EXCLUDE
+    # Workaround: migrate old default values to a regex (see #90).
+    set Z_EXCLUDE (string replace -r -- "^$HOME\$" '^'$HOME'$$' $Z_EXCLUDE)
+end
+
+# Setup completions once first
+__z_complete
+
+function __z_on_variable_pwd --on-variable PWD
+    __z_add
+end
+
+function __z_uninstall --on-event z_uninstall
+    functions -e __z_on_variable_pwd
+    functions -e $Z_CMD
+    functions -e $ZO_CMD
+
+    if test ! -z "$Z_DATA"
+        printf "To completely erase z's data, remove:\n" >/dev/stderr
+        printf "%s\n" "$Z_DATA" >/dev/stderr
+    end
+
+    set -e Z_CMD
+    set -e ZO_CMD
+    set -e Z_DATA
+    set -e Z_EXCLUDE
+end