feat(config): fish: meaningful-ooo/sponge

Signed-off-by: Ismo Vuorinen <ismo@ivuorinen.net>

config/fish/functions/_sponge_clear_state.fish

@@ -0,0 +1,5 @@
+function _sponge_clear_state
+  set --erase --global _sponge_current_command
+  set --erase --global _sponge_current_command_exit_code
+  set --erase --global _sponge_current_command_previously_in_history
+end

config/fish/functions/_sponge_on_exit.fish

@@ -0,0 +1,3 @@
+function _sponge_on_exit --on-event fish_exit
+  sponge_delay=0 _sponge_remove_from_history
+end

config/fish/functions/_sponge_on_postexec.fish

@@ -0,0 +1,24 @@
+function _sponge_on_postexec --on-event fish_postexec
+  set --global _sponge_current_command_exit_code $status
+
+  # Remove command from the queue if it's been added previously
+  if set --local index (contains --index -- $_sponge_current_command $_sponge_queue)
+    set --erase _sponge_queue[$index]
+  end
+
+  # Ignore empty commands
+  if test -n $_sponge_current_command
+    set --local command ''
+    # Run filters
+    for filter in $sponge_filters
+      if $filter \
+          $_sponge_current_command \
+          $_sponge_current_command_exit_code \
+          $_sponge_current_command_previously_in_history
+        set command $_sponge_current_command
+        break
+      end
+    end
+    set --prepend --global _sponge_queue $command
+  end
+end

config/fish/functions/_sponge_on_preexec.fish

@@ -0,0 +1,16 @@
+function _sponge_on_preexec --on-event fish_preexec \
+  --argument-names command
+  _sponge_clear_state
+
+  set --global _sponge_current_command $command
+
+  builtin history search --case-sensitive --exact --max=1 --null $command \
+    | read --local --null found_entries
+
+  # If a command is in the history and in the queue, ignore it, like if it wasn’t in the history
+  if test (count $found_entries) -ne 0; and not contains $command $_sponge_queue
+    set --global _sponge_current_command_previously_in_history true
+  else
+    set --global _sponge_current_command_previously_in_history false
+  end
+end

config/fish/functions/_sponge_on_prompt.fish

@@ -0,0 +1,5 @@
+function _sponge_on_prompt --on-event fish_prompt
+  if test $sponge_purge_only_on_exit = false
+    _sponge_remove_from_history
+  end
+end

config/fish/functions/_sponge_remove_from_history.fish

@@ -0,0 +1,9 @@
+function _sponge_remove_from_history
+
+  while test (count $_sponge_queue) -gt $sponge_delay
+    builtin history delete --case-sensitive --exact -- $_sponge_queue[-1]
+    set --erase _sponge_queue[-1]
+  end
+
+  builtin history save
+end

config/fish/functions/sponge_filter_failed.fish

@@ -0,0 +1,11 @@
+function sponge_filter_failed \
+  --argument-names command exit_code previously_in_history
+
+  if test $previously_in_history = true -a $sponge_allow_previously_successful = true
+    return 1
+  end
+
+  if contains $exit_code $sponge_successful_exit_codes
+    return 1
+  end
+end

config/fish/functions/sponge_filter_matched.fish

@@ -0,0 +1,11 @@
+function sponge_filter_matched \
+  --argument-names command
+
+  for pattern in $sponge_regex_patterns
+    if string match --regex --quiet $pattern -- $command
+      return
+    end
+  end
+
+  return 1
+end