chore(git): add masf to git profile

Signed-off-by: Ismo Vuorinen <ismo@ivuorinen.net>

.github/workflows/linters.yml

@@ -33,4 +33,4 @@ jobs:
 
       - name: Run PR Lint
         # https://github.com/ivuorinen/actions
-        uses: ivuorinen/actions/pr-lint@c0f919957eb60743682a6e0cd6d454fd4b142ac9 # 25.6.30
+        uses: ivuorinen/actions/pr-lint@625c37446b1c7e219755a40807f825c9283f6e05 # 25.7.7

.github/workflows/sync-labels.yml

@@ -29,4 +29,4 @@ jobs:
       issues: write
 
     steps:
-      - uses: ivuorinen/actions/sync-labels@c0f919957eb60743682a6e0cd6d454fd4b142ac9 # 25.6.30
+      - uses: ivuorinen/actions/sync-labels@625c37446b1c7e219755a40807f825c9283f6e05 # 25.7.7

.pre-commit-config.yaml

@@ -39,7 +39,7 @@ repos:
       - id: shellcheck
 
   - repo: https://github.com/scop/pre-commit-shfmt
-    rev: v3.11.0-1
+    rev: v3.12.0-1
     hooks:
       - id: shfmt
 
@@ -49,7 +49,7 @@ repos:
       - id: actionlint
 
   - repo: https://github.com/renovatebot/pre-commit-hooks
-    rev: 41.17.2
+    rev: 41.23.5
     hooks:
       - id: renovate-config-validator
 

AGENTS.md

@@ -0,0 +1,34 @@
+# Project guidelines
+
+This repository contains configuration files and helper scripts for managing a development environment. Dotbot drives the installation and host specific folders under `hosts/` include extra configs.
+
+## Keeping the repository up to date
+
+1. Update submodules with `git submodule update --remote --merge`.
+2. Pull the latest changes and run `./install`.
+3. Run `yarn install` whenever `package.json` changes.
+
+## Linting and tests
+
+- Format files with:
+
+  ```bash
+  yarn fix:prettier
+  yarn fix:markdown
+  ```
+
+- Shell scripts must pass `shellcheck`. Run:
+
+  ```bash
+  find . -path ./node_modules -prune -o -name '*.sh' -print0 | xargs -0 shellcheck
+  ```
+
+- Execute tests with `yarn test`.
+
+## Debugging lint issues
+
+- `yarn lint:prettier` and `yarn lint:markdown` show formatting errors.
+- Ensure shell scripts have a shebang or `# shellcheck shell=bash` directive.
+- Consult `.shellcheckrc` for project specific checks.
+
+Scripts rely on helpers in `config/shared.sh` so they run under Bash, Zsh and Fish by default.

base/gitprofile

@@ -20,6 +20,16 @@
         "value": "Ismo Vuorinen"
       }
     ],
+    "masf": [
+      {
+        "key": "user.email",
+        "value": "ismo@masf.fi"
+      },
+      {
+        "key": "user.name",
+        "value": "Ismo Vuorinen"
+      }
+    ],
     "work": [
       {
         "key": "user.email",

config/asdf/golang-packages

@@ -1,8 +1,6 @@
 // These are golang packages I use,
 // so they should be available with all versions
 
-// Aqua is a package manager like asdf, or Brew
-github.com/aquaproj/aqua/v2/cmd/aqua@latest
 // Git Profile allows you to switch between user profiles in git repos
 github.com/dotzero/git-profile@v1.4.0
 // An extensible command line tool or library to format yaml files.
@@ -21,3 +19,8 @@ github.com/rhysd/actionlint/cmd/actionlint@v1.7.1
 github.com/doron-cohen/antidot@v0.6.3
 // FZF is a general-purpose command-line fuzzy finder.
 github.com/junegunn/fzf@latest
+// gopls, the Go language server
+golang.org/x/tools/gopls@latest
+// A language for writing HTML user interfaces in Go.
+github.com/a-h/templ/cmd/templ@latest
+

config/direnv/lib/use_asdf.sh

@@ -1,4 +1,5 @@
 ### Do not edit. This was autogenerated by 'asdf direnv setup' ###
+# shellcheck shell=bash
 use_asdf() {
   source_env "$(asdf direnv envrc "$@")"
 }

config/fish/completions/fzf_configure_bindings.fish

@@ -0,0 +1,8 @@
+complete fzf_configure_bindings --no-files
+complete fzf_configure_bindings --long help --short h --description "Print help" --condition "not __fish_seen_argument --help -h"
+complete fzf_configure_bindings --long directory --description "Change the key binding for Search Directory" --condition "not __fish_seen_argument --directory"
+complete fzf_configure_bindings --long git_log --description "Change the key binding for Search Git Log" --condition "not __fish_seen_argument --git_log"
+complete fzf_configure_bindings --long git_status --description "Change the key binding for Search Git Status" --condition "not __fish_seen_argument --git_status"
+complete fzf_configure_bindings --long history --description "Change the key binding for Search History" --condition "not __fish_seen_argument --history"
+complete fzf_configure_bindings --long processes --description "Change the key binding for Search Processes" --condition "not __fish_seen_argument --processes"
+complete fzf_configure_bindings --long variables --description "Change the key binding for Search Variables" --condition "not __fish_seen_argument --variables"

config/fish/conf.d/fzf.fish

@@ -0,0 +1,28 @@
+# fzf.fish is only meant to be used in interactive mode. If not in interactive mode and not in CI, skip the config to speed up shell startup
+if not status is-interactive && test "$CI" != true
+    exit
+end
+
+# Because of scoping rules, to capture the shell variables exactly as they are, we must read
+# them before even executing _fzf_search_variables. We use psub to store the
+# variables' info in temporary files and pass in the filenames as arguments.
+# This variable is global so that it can be referenced by fzf_configure_bindings and in tests
+set --global _fzf_search_vars_command '_fzf_search_variables (set --show | psub) (set --names | psub)'
+
+
+# Install the default bindings, which are mnemonic and minimally conflict with fish's preset bindings
+fzf_configure_bindings
+
+# Doesn't erase autoloaded _fzf_* functions because they are not easily accessible once key bindings are erased
+function _fzf_uninstall --on-event fzf_uninstall
+    _fzf_uninstall_bindings
+
+    set --erase _fzf_search_vars_command
+    functions --erase _fzf_uninstall _fzf_migration_message _fzf_uninstall_bindings fzf_configure_bindings
+    complete --erase fzf_configure_bindings
+
+    set_color cyan
+    echo "fzf.fish uninstalled."
+    echo "You may need to manually remove fzf_configure_bindings from your config.fish if you were using custom key bindings."
+    set_color normal
+end

config/fish/fish_plugins

@@ -8,3 +8,4 @@ edc/bass
 meaningful-ooo/sponge
 nickeb96/puffer-fish
 jgusta/paths
+patrickf1/fzf.fish

config/fish/functions/_fzf_configure_bindings_help.fish

@@ -0,0 +1,43 @@
+function _fzf_configure_bindings_help --description "Prints the help message for fzf_configure_bindings."
+    echo "\
+USAGE:
+    fzf_configure_bindings [--COMMAND=[KEY_SEQUENCE]...]
+
+DESCRIPTION
+    fzf_configure_bindings installs key bindings for fzf.fish's commands and erases any bindings it
+    previously installed. It installs bindings for both default and insert modes. fzf.fish executes
+    it without options on fish startup to install the out-of-the-box key bindings.
+
+    By default, commands are bound to a mnemonic key sequence, shown below. Each command's binding
+    can be configured using a namesake corresponding option:
+        COMMAND            |  DEFAULT KEY SEQUENCE         |  CORRESPONDING OPTION
+        Search Directory   |  Ctrl+Alt+F (F for file)      |  --directory
+        Search Git Log     |  Ctrl+Alt+L (L for log)       |  --git_log
+        Search Git Status  |  Ctrl+Alt+S (S for status)    |  --git_status
+        Search History     |  Ctrl+R     (R for reverse)   |  --history
+        Search Processes   |  Ctrl+Alt+P (P for process)   |  --processes
+        Search Variables   |  Ctrl+V     (V for variable)  |  --variables
+    Override a command's binding by specifying its corresponding option with the desired key
+    sequence. Disable a command's binding by specifying its corresponding option with no value.
+
+    Because fzf_configure_bindings erases bindings it previously installed, it can be cleanly
+    executed multiple times. Once the desired fzf_configure_bindings command has been found, add it
+    to your config.fish in order to persist the customized bindings.
+
+    In terms of validation, fzf_configure_bindings fails if passed unknown options. It expects an
+    equals sign between an option's name and value. However, it does not validate key sequences.
+
+    Pass -h or --help to print this help message and exit.
+
+EXAMPLES
+    Default bindings but bind Search Directory to Ctrl+F and Search Variables to Ctrl+Alt+V
+        \$ fzf_configure_bindings --directory=\cf --variables=\e\cv
+    Default bindings but disable Search History
+        \$ fzf_configure_bindings --history=
+    An agglomeration of different options
+        \$ fzf_configure_bindings --git_status=\cg --history=\ch --variables= --processes=
+
+SEE Also
+    To learn more about fish key bindings, see bind(1) and fish_key_reader(1).
+"
+end

config/fish/functions/_fzf_extract_var_info.fish

@@ -0,0 +1,15 @@
+# helper function for _fzf_search_variables
+function _fzf_extract_var_info --argument-names variable_name set_show_output --description "Extract and reformat lines pertaining to \$variable_name from \$set_show_output."
+    # Extract only the lines about the variable, all of which begin with either
+    # $variable_name: ...or... $variable_name[
+    string match --regex "^\\\$$variable_name(?::|\[).*" <$set_show_output |
+
+        # Strip the variable name prefix, including ": " for scope info lines
+        string replace --regex "^\\\$$variable_name(?:: )?" '' |
+
+        # Distill the lines of values, replacing...
+        #   [1]: |value|
+        # ...with...
+        #   [1] value
+        string replace --regex ": \|(.*)\|" ' $1'
+end

config/fish/functions/_fzf_preview_changed_file.fish

@@ -0,0 +1,49 @@
+# helper for _fzf_search_git_status
+# arg should be a line from git status --short, e.g.
+# MM functions/_fzf_preview_changed_file.fish
+#  D README.md
+# R  LICENSE -> "New License"
+function _fzf_preview_changed_file --argument-names path_status --description "Show the git diff of the given file."
+    # remove quotes because they'll be interpreted literally by git diff
+    # no need to requote when referencing $path because fish does not perform word splitting
+    # https://fishshell.com/docs/current/fish_for_bash_users.html
+    set -f path (string unescape (string sub --start 4 $path_status))
+    # first letter of short format shows index, second letter shows working tree
+    # https://git-scm.com/docs/git-status/2.35.0#_short_format
+    set -f index_status (string sub --length 1 $path_status)
+    set -f working_tree_status (string sub --start 2 --length 1 $path_status)
+
+    set -f diff_opts --color=always
+
+    if test $index_status = '?'
+        _fzf_report_diff_type Untracked
+        _fzf_preview_file $path
+    else if contains {$index_status}$working_tree_status DD AU UD UA DU AA UU
+        # Unmerged statuses taken directly from git status help's short format table
+        # Unmerged statuses are mutually exclusive with other statuses, so if we see
+        # these, then safe to assume the path is unmerged
+        _fzf_report_diff_type Unmerged
+        git diff $diff_opts -- $path
+    else
+        if test $index_status != ' '
+            _fzf_report_diff_type Staged
+
+            # renames are only detected in the index, never working tree, so only need to test for it here
+            # https://stackoverflow.com/questions/73954214
+            if test $index_status = R
+                # diff the post-rename path with the original path, otherwise the diff will show the entire file as being added
+                set -f orig_and_new_path (string split --max 1 -- ' -> ' $path)
+                git diff --staged $diff_opts -- $orig_and_new_path[1] $orig_and_new_path[2]
+                # path currently has the form of "original -> current", so we need to correct it before it's used below
+                set path $orig_and_new_path[2]
+            else
+                git diff --staged $diff_opts -- $path
+            end
+        end
+
+        if test $working_tree_status != ' '
+            _fzf_report_diff_type Unstaged
+            git diff $diff_opts -- $path
+        end
+    end
+end

config/fish/functions/_fzf_preview_file.fish

@@ -0,0 +1,43 @@
+# helper function for _fzf_search_directory and _fzf_search_git_status
+function _fzf_preview_file --description "Print a preview for the given file based on its file type."
+    # because there's no way to guarantee that _fzf_search_directory passes the path to _fzf_preview_file
+    # as one argument, we collect all the arguments into one single variable and treat that as the path
+    set -f file_path $argv
+
+    if test -L "$file_path" # symlink
+        # notify user and recurse on the target of the symlink, which can be any of these file types
+        set -l target_path (realpath "$file_path")
+
+        set_color yellow
+        echo "'$file_path' is a symlink to '$target_path'."
+        set_color normal
+
+        _fzf_preview_file "$target_path"
+    else if test -f "$file_path" # regular file
+        if set --query fzf_preview_file_cmd
+            # need to escape quotes to make sure eval receives file_path as a single arg
+            eval "$fzf_preview_file_cmd '$file_path'"
+        else
+            bat --style=numbers --color=always "$file_path"
+        end
+    else if test -d "$file_path" # directory
+        if set --query fzf_preview_dir_cmd
+            # see above
+            eval "$fzf_preview_dir_cmd '$file_path'"
+        else
+            # -A list hidden files as well, except for . and ..
+            # -F helps classify files by appending symbols after the file name
+            command ls -A -F "$file_path"
+        end
+    else if test -c "$file_path"
+        _fzf_report_file_type "$file_path" "character device file"
+    else if test -b "$file_path"
+        _fzf_report_file_type "$file_path" "block device file"
+    else if test -S "$file_path"
+        _fzf_report_file_type "$file_path" socket
+    else if test -p "$file_path"
+        _fzf_report_file_type "$file_path" "named pipe"
+    else
+        echo "$file_path doesn't exist." >&2
+    end
+end

config/fish/functions/_fzf_report_diff_type.fish

@@ -0,0 +1,18 @@
+# helper for _fzf_preview_changed_file
+# prints out something like
+# ╭────────╮
+# │ Staged │
+# ╰────────╯
+function _fzf_report_diff_type --argument-names diff_type --description "Print a distinct colored header meant to preface a git patch."
+    # number of "-" to draw is the length of the string to box + 2 for padding
+    set -f repeat_count (math 2 + (string length $diff_type))
+    set -f line (string repeat --count $repeat_count ─)
+    set -f top_border ╭$line╮
+    set -f btm_border ╰$line╯
+
+    set_color yellow
+    echo $top_border
+    echo "│ $diff_type │"
+    echo $btm_border
+    set_color normal
+end

config/fish/functions/_fzf_report_file_type.fish

@@ -0,0 +1,6 @@
+# helper function for _fzf_preview_file
+function _fzf_report_file_type --argument-names file_path file_type --description "Explain the file type for a file."
+    set_color red
+    echo "Cannot preview '$file_path': it is a $file_type."
+    set_color normal
+end

config/fish/functions/_fzf_search_directory.fish

@@ -0,0 +1,33 @@
+function _fzf_search_directory --description "Search the current directory. Replace the current token with the selected file paths."
+    # Directly use fd binary to avoid output buffering delay caused by a fd alias, if any.
+    # Debian-based distros install fd as fdfind and the fd package is something else, so
+    # check for fdfind first. Fall back to "fd" for a clear error message.
+    set -f fd_cmd (command -v fdfind || command -v fd  || echo "fd")
+    set -f --append fd_cmd --color=always $fzf_fd_opts
+
+    set -f fzf_arguments --multi --ansi $fzf_directory_opts
+    set -f token (commandline --current-token)
+    # expand any variables or leading tilde (~) in the token
+    set -f expanded_token (eval echo -- $token)
+    # unescape token because it's already quoted so backslashes will mess up the path
+    set -f unescaped_exp_token (string unescape -- $expanded_token)
+
+    # If the current token is a directory and has a trailing slash,
+    # then use it as fd's base directory.
+    if string match --quiet -- "*/" $unescaped_exp_token && test -d "$unescaped_exp_token"
+        set --append fd_cmd --base-directory=$unescaped_exp_token
+        # use the directory name as fzf's prompt to indicate the search is limited to that directory
+        set --prepend fzf_arguments --prompt="Directory $unescaped_exp_token> " --preview="_fzf_preview_file $expanded_token{}"
+        set -f file_paths_selected $unescaped_exp_token($fd_cmd 2>/dev/null | _fzf_wrapper $fzf_arguments)
+    else
+        set --prepend fzf_arguments --prompt="Directory> " --query="$unescaped_exp_token" --preview='_fzf_preview_file {}'
+        set -f file_paths_selected ($fd_cmd 2>/dev/null | _fzf_wrapper $fzf_arguments)
+    end
+
+
+    if test $status -eq 0
+        commandline --current-token --replace -- (string escape -- $file_paths_selected | string join ' ')
+    end
+
+    commandline --function repaint
+end

config/fish/functions/_fzf_search_git_log.fish

@@ -0,0 +1,36 @@
+function _fzf_search_git_log --description "Search the output of git log and preview commits. Replace the current token with the selected commit hash."
+    if not git rev-parse --git-dir >/dev/null 2>&1
+        echo '_fzf_search_git_log: Not in a git repository.' >&2
+    else
+        if not set --query fzf_git_log_format
+            # %h gives you the abbreviated commit hash, which is useful for saving screen space, but we will have to expand it later below
+            set -f fzf_git_log_format '%C(bold blue)%h%C(reset) - %C(cyan)%ad%C(reset) %C(yellow)%d%C(reset) %C(normal)%s%C(reset)  %C(dim normal)[%an]%C(reset)'
+        end
+
+        set -f preview_cmd 'git show --color=always --stat --patch {1}'
+        if set --query fzf_diff_highlighter
+            set preview_cmd "$preview_cmd | $fzf_diff_highlighter"
+        end
+
+        set -f selected_log_lines (
+            git log --no-show-signature --color=always --format=format:$fzf_git_log_format --date=short | \
+            _fzf_wrapper --ansi \
+                --multi \
+                --scheme=history \
+                --prompt="Git Log> " \
+                --preview=$preview_cmd \
+                --query=(commandline --current-token) \
+                $fzf_git_log_opts
+        )
+        if test $status -eq 0
+            for line in $selected_log_lines
+                set -f abbreviated_commit_hash (string split --field 1 " " $line)
+                set -f full_commit_hash (git rev-parse $abbreviated_commit_hash)
+                set -f --append commit_hashes $full_commit_hash
+            end
+            commandline --current-token --replace (string join ' ' $commit_hashes)
+        end
+    end
+
+    commandline --function repaint
+end

config/fish/functions/_fzf_search_git_status.fish

@@ -0,0 +1,41 @@
+function _fzf_search_git_status --description "Search the output of git status. Replace the current token with the selected file paths."
+    if not git rev-parse --git-dir >/dev/null 2>&1
+        echo '_fzf_search_git_status: Not in a git repository.' >&2
+    else
+        set -f preview_cmd '_fzf_preview_changed_file {}'
+        if set --query fzf_diff_highlighter
+            set preview_cmd "$preview_cmd | $fzf_diff_highlighter"
+        end
+
+        set -f selected_paths (
+            # Pass configuration color.status=always to force status to use colors even though output is sent to a pipe
+            git -c color.status=always status --short |
+            _fzf_wrapper --ansi \
+                --multi \
+                --prompt="Git Status> " \
+                --query=(commandline --current-token) \
+                --preview=$preview_cmd \
+                --nth="2.." \
+                $fzf_git_status_opts
+        )
+        if test $status -eq 0
+            # git status --short automatically escapes the paths of most files for us so not going to bother trying to handle
+            # the few edges cases of weird file names that should be extremely rare (e.g. "this;needs;escaping")
+            set -f cleaned_paths
+
+            for path in $selected_paths
+                if test (string sub --length 1 $path) = R
+                    # path has been renamed and looks like "R LICENSE -> LICENSE.md"
+                    # extract the path to use from after the arrow
+                    set --append cleaned_paths (string split -- "-> " $path)[-1]
+                else
+                    set --append cleaned_paths (string sub --start=4 $path)
+                end
+            end
+
+            commandline --current-token --replace -- (string join ' ' $cleaned_paths)
+        end
+    end
+
+    commandline --function repaint
+end

config/fish/functions/_fzf_search_history.fish

@@ -0,0 +1,39 @@
+function _fzf_search_history --description "Search command history. Replace the command line with the selected command."
+    # history merge incorporates history changes from other fish sessions
+    # it errors out if called in private mode
+    if test -z "$fish_private_mode"
+        builtin history merge
+    end
+
+    if not set --query fzf_history_time_format
+        # Reference https://devhints.io/strftime to understand strftime format symbols
+        set -f fzf_history_time_format "%m-%d %H:%M:%S"
+    end
+
+    # Delinate time from command in history entries using the vertical box drawing char (U+2502).
+    # Then, to get raw command from history entries, delete everything up to it. The ? on regex is
+    # necessary to make regex non-greedy so it won't match into commands containing the char.
+    set -f time_prefix_regex '^.*? │ '
+    # Delinate commands throughout pipeline using null rather than newlines because commands can be multi-line
+    set -f commands_selected (
+        builtin history --null --show-time="$fzf_history_time_format │ " |
+        _fzf_wrapper --read0 \
+            --print0 \
+            --multi \
+            --scheme=history \
+            --prompt="History> " \
+            --query=(commandline) \
+            --preview="string replace --regex '$time_prefix_regex' '' -- {} | fish_indent --ansi" \
+            --preview-window="bottom:3:wrap" \
+            $fzf_history_opts |
+        string split0 |
+        # remove timestamps from commands selected
+        string replace --regex $time_prefix_regex ''
+    )
+
+    if test $status -eq 0
+        commandline --replace -- $commands_selected
+    end
+
+    commandline --function repaint
+end

config/fish/functions/_fzf_search_processes.fish

@@ -0,0 +1,32 @@
+function _fzf_search_processes --description "Search all running processes. Replace the current token with the pid of the selected process."
+    # Directly use ps command because it is often aliased to a different command entirely
+    # or with options that dirty the search results and preview output
+    set -f ps_cmd (command -v ps || echo "ps")
+    # use all caps to be consistent with ps default format
+    # snake_case because ps doesn't seem to allow spaces in the field names
+    set -f ps_preview_fmt (string join ',' 'pid' 'ppid=PARENT' 'user' '%cpu' 'rss=RSS_IN_KB' 'start=START_TIME' 'command')
+    set -f processes_selected (
+        $ps_cmd -A -opid,command | \
+        _fzf_wrapper --multi \
+                    --prompt="Processes> " \
+                    --query (commandline --current-token) \
+                    --ansi \
+                    # first line outputted by ps is a header, so we need to mark it as so
+                    --header-lines=1 \
+                    # ps uses exit code 1 if the process was not found, in which case show an message explaining so
+                    --preview="$ps_cmd -o '$ps_preview_fmt' -p {1} || echo 'Cannot preview {1} because it exited.'" \
+                    --preview-window="bottom:4:wrap" \
+                    $fzf_processes_opts
+    )
+
+    if test $status -eq 0
+        for process in $processes_selected
+            set -f --append pids_selected (string split --no-empty --field=1 -- " " $process)
+        end
+
+        # string join to replace the newlines outputted by string split with spaces
+        commandline --current-token --replace -- (string join ' ' $pids_selected)
+    end
+
+    commandline --function repaint
+end

config/fish/functions/_fzf_search_variables.fish

@@ -0,0 +1,47 @@
+# This function expects the following two arguments:
+# argument 1 = output of (set --show | psub), i.e. a file with the scope info and values of all variables
+# argument 2 = output of (set --names | psub), i.e. a file with all variable names
+function _fzf_search_variables --argument-names set_show_output set_names_output --description "Search and preview shell variables. Replace the current token with the selected variable."
+    if test -z "$set_names_output"
+        printf '%s\n' '_fzf_search_variables requires 2 arguments.' >&2
+
+        commandline --function repaint
+        return 22 # 22 means invalid argument in POSIX
+    end
+
+    # Exclude the history variable from being piped into fzf because
+    # 1. it's not included in $set_names_output
+    # 2. it tends to be a very large value => increases computation time
+    # 3._fzf_search_history is a much better way to examine history anyway
+    set -f all_variable_names (string match --invert history <$set_names_output)
+
+    set -f current_token (commandline --current-token)
+    # Use the current token to pre-populate fzf's query. If the current token begins
+    # with a $, remove it from the query so that it will better match the variable names
+    set -f cleaned_curr_token (string replace -- '$' '' $current_token)
+
+    set -f variable_names_selected (
+        printf '%s\n' $all_variable_names |
+        _fzf_wrapper --preview "_fzf_extract_var_info {} $set_show_output" \
+            --prompt="Variables> " \
+            --preview-window="wrap" \
+            --multi \
+            --query=$cleaned_curr_token \
+            $fzf_variables_opts
+    )
+
+    if test $status -eq 0
+        # If the current token begins with a $, do not overwrite the $ when
+        # replacing the current token with the selected variable.
+        # Uses brace expansion to prepend $ to each variable name.
+        commandline --current-token --replace (
+            if string match --quiet -- '$*' $current_token
+                string join " " \${$variable_names_selected}
+            else
+                string join " " $variable_names_selected
+            end
+        )
+    end
+
+    commandline --function repaint
+end

config/fish/functions/_fzf_wrapper.fish

@@ -0,0 +1,21 @@
+function _fzf_wrapper --description "Prepares some environment variables before executing fzf."
+    # Make sure fzf uses fish to execute preview commands, some of which
+    # are autoloaded fish functions so don't exist in other shells.
+    # Use --function so that it doesn't clobber SHELL outside this function.
+    set -f --export SHELL (command --search fish)
+
+    # If neither FZF_DEFAULT_OPTS nor FZF_DEFAULT_OPTS_FILE are set, then set some sane defaults.
+    # See https://github.com/junegunn/fzf#environment-variables
+    set --query FZF_DEFAULT_OPTS FZF_DEFAULT_OPTS_FILE
+    if test $status -eq 2
+        # cycle allows jumping between the first and last results, making scrolling faster
+        # layout=reverse lists results top to bottom, mimicking the familiar layouts of git log, history, and env
+        # border shows where the fzf window begins and ends
+        # height=90% leaves space to see the current command and some scrollback, maintaining context of work
+        # preview-window=wrap wraps long lines in the preview window, making reading easier
+        # marker=* makes the multi-select marker more distinguishable from the pointer (since both default to >)
+        set --export FZF_DEFAULT_OPTS '--cycle --layout=reverse --border --height=90% --preview-window=wrap --marker="*"'
+    end
+
+    fzf $argv
+end

config/fish/functions/cr.fish

@@ -0,0 +1,303 @@
+# cr.fish — Create and manage code review worktrees for Fish shell
+#
+# Synopsis:
+#   cr [OPTIONS] <source-branch>
+#   cr cleanup [OPTIONS]
+#
+# Description:
+#   Create a dedicated worktree for reviewing code based on a ticket ID
+#   extracted from a branch name, or clean up existing cr- worktrees.
+#
+# Constants:
+#   CR_DEFAULT_REMOTE      Default Git remote used when none specified
+#
+# Fish Requirements:
+#   Fish shell >= 3.1.0 for argparse builtin
+#
+# Based on work by ville6000 (https://github.com/ville6000)
+#
+# Examples:
+#   cr feature/1234-add-login
+#   cr -r upstream 5678
+#   cr cleanup --dry-run
+
+if not set -q CR_DEFAULT_REMOTE
+    set -g CR_DEFAULT_REMOTE origin
+end
+
+function __cr_show_help
+    echo 'Usage: cr [OPTIONS] <source-branch>'
+    echo '       cr cleanup [OPTIONS]'
+    echo
+    echo "  -r, --remote <name>        Git remote (default: $CR_DEFAULT_REMOTE)"
+    echo '  -d, --dry-run              Show actions without executing'
+    echo '  -f, --force                Skip confirmation prompts'
+    echo '  -k, --keep-branch          In cleanup, keep local branches'
+    echo '  -b, --branch-only <ticket> Create only the review branch (no worktree)'
+    echo '      --cleanup-branches-only In cleanup, delete branches only'
+    echo '  -h, --help                 Show this help'
+end
+
+function __cr_run_with_spinner --argument-names msg cmd
+    set -l tmp (mktemp)
+    eval $cmd >$tmp 2>&1 &
+    set -l pid $last_pid
+    set -l spin_chars '/-\|'
+    set -l i 1
+    while kill -0 $pid 2>/dev/null
+        printf "\r[%c] %s" (string sub -s $i -l 1 $spin_chars) "$msg"
+        set i (math (math $i % 4) + 1)
+        sleep 0.1
+    end
+    printf "\r%s\r" (string repeat -n (math (string length "$msg") + 5) " ")
+    wait $pid
+    set -l output (cat $tmp)
+    rm $tmp
+    # Remove any leading empty or all-whitespace lines (from spinner clear)
+    for line in $output
+        if test -n (string trim -- $line)
+            echo $line
+        end
+    end
+end
+
+function __cr_cleanup
+    argparse dry_run force keep_branch cleanup_branches_only -- $argv
+    or return
+
+    set -l dry_run (set -q _flag_dry_run; and echo 1; or echo 0)
+    set -l force (set -q _flag_force; and echo 1; or echo 0)
+    set -l keep_branch (set -q _flag_keep_branch; and echo 1; or echo 0)
+    set -l branches_only (set -q _flag_cleanup_branches_only; and echo 1; or echo 0)
+
+    set -l target_branch
+    if test (count $argv) -gt 0
+        set target_branch $argv[1]
+    end
+
+    git worktree prune
+
+    for wt in (git worktree list --porcelain | awk '/^worktree /{print $2}')
+        set -l base (basename $wt)
+        if string match -r '^cr-.*' $base
+            if test -n "$target_branch" -a "$base" != "$target_branch"
+                continue
+            end
+            if test "$branches_only" = 0
+                if test "$dry_run" = 1
+                    echo "[DRY-RUN] remove worktree: $wt"
+                else if test "$force" = 1
+                    git worktree remove --force $wt
+                else
+                    echo "git worktree remove --force $wt"
+                    echo "(!) Use --force to actually remove worktree: $wt."
+                end
+            end
+            if test "$keep_branch" = 0
+                if test "$branches_only" = 0
+                    if test "$dry_run" = 1
+                        echo "[DRY-RUN] delete branch: $base"
+                    else if test "$force" = 1
+                        git branch -D $base
+                    else
+                        echo "git branch -D $base"
+                        echo "(!) Use --force to actually delete branch: $base."
+                    end
+                end
+            end
+        end
+    end
+end
+
+# --- Main Entrypoint ---
+
+function cr --description 'Create or cleanup code-review worktrees'
+    if not git rev-parse --is-inside-work-tree >/dev/null 2>&1
+        echo "Not inside a git repository." >&2
+        return 1
+    end
+
+    set -l remotes (git remote)
+    if test (count $remotes) -eq 0
+        echo "No git remotes found. Please add a remote before using cr." >&2
+        return 1
+    end
+
+    if not type -q argparse
+        echo 'cr.fish requires the argparse builtin' >&2
+        return 1
+    end
+
+    argparse \
+        r/remote= \
+        h/help \
+        d/dry-run \
+        f/force \
+        y/yes \
+        k/keep-branch \
+        b/branch-only= \
+        cleanup-branches-only \
+        -- $argv
+    or return
+
+    if set -q _flag_h; or set -q _flag_help
+        __cr_show_help
+        return 0
+    end
+
+    set -l remote (set -q _flag_remote; and echo $_flag_remote[-1]; or echo $CR_DEFAULT_REMOTE)
+    if set -q _flag_yes
+        set -g _flag_force 1
+    end
+
+    if not contains $remote $remotes
+        echo "Remote '$remote' does not exist. Available remotes: $remotes" >&2
+        return 1
+    end
+
+    if test (count $argv) -gt 0 -a "$argv[1]" = cleanup
+        __cr_cleanup \
+            (set -q _flag_dry_run; and echo --dry_run) \
+            (set -q _flag_force; and echo --force) \
+            (set -q _flag_keep_branch; and echo --keep_branch) \
+            (set -q _flag_cleanup_branches_only; and echo --cleanup_branches_only)
+        return 0
+    end
+
+    set -l source_branch ""
+    if test (count $argv) -gt 0
+        set source_branch $argv[1]
+    else if type -q fzf
+        set -l branches (__cr_run_with_spinner "Fetching branches..." \
+            "git ls-remote --heads $remote | sed 's|.*refs/heads/||'")
+        printf "\n"
+        if test (count $branches) -eq 0
+            echo "No branches found on remote '$remote'." >&2
+            return 1
+        end
+        set -l exclude_branches main master develop dev trunk
+        set -l filtered_branches
+        for b in $branches
+            set b (string trim -- $b)
+            if not contains -- $b $exclude_branches
+                set filtered_branches $filtered_branches $b
+            end
+        end
+        set source_branch (printf '%s\n' $filtered_branches | fzf --prompt='Select branch: ')
+        echo "Selected branch: $source_branch"
+        if test $status -ne 0
+            echo 'Selection aborted' >&2
+            return 1
+        end
+        if test -z "$source_branch"
+            echo 'No branch selected' >&2
+            return 1
+        end
+    else
+        __cr_show_help >&2
+        return 1
+    end
+
+    # Extract ticket ID from branch name, or use slug if not found
+    set -l branch_tail (string split "/" $source_branch)[-1]
+    set -l ticket_id (printf '%s\n' $branch_tail | grep -o '[0-9]\+' | tail -n1)
+    set -l review_suffix ""
+    if test -z "$ticket_id"
+        # No numeric ticket, use slug of branch name as suffix
+        set review_suffix (string replace -ra '[^a-zA-Z0-9]+' '-' -- $source_branch)
+    else
+        set review_suffix $ticket_id
+    end
+    if set -q _flag_b; or set -q _flag_branch_only
+        set review_suffix $_flag_branch_only[-1]
+    end
+    set -l review_branch cr-$review_suffix
+    set -l folder ../$review_branch
+
+    # Branch-only mode
+    if set -q _flag_b; or set -q _flag_branch_only
+        if set -q _flag_dry_run
+            echo "[DRY-RUN] Create branch $review_branch from $remote/$source_branch"
+            return 0
+        end
+        __cr_run_with_spinner "Fetching from $remote..." \
+            "git fetch $remote $source_branch"
+        git branch $review_branch $remote/$source_branch
+        echo "Created branch $review_branch"
+        return 0
+    end
+
+    __cr_run_with_spinner "Checking remote branch..." \
+        "git ls-remote --exit-code --heads $remote $source_branch >/dev/null 2>&1"
+    if test $status -ne 0
+        echo "No remote branch $remote/$source_branch" >&2
+        return 1
+    end
+    if git show-ref --quiet refs/heads/$review_branch
+        echo "Local branch $review_branch exists" >&2
+        return 1
+    end
+    if test -d $folder
+        echo "Directory $folder exists" >&2
+        return 1
+    end
+
+    if set -q _flag_dry_run
+        echo "[DRY-RUN] Add worktree $folder -b $review_branch $remote/$source_branch"
+        return 0
+    end
+
+    __cr_run_with_spinner "Fetching from $remote..." \
+        "git fetch $remote $source_branch"
+    git worktree add $folder -b $review_branch $remote/$source_branch
+end
+
+# --- Completion Functions ---
+
+complete -c cr -l help -s h -f -d 'Show help'
+complete -c cr -l remote -s r -f -d 'Git remote' -a '(git remote)'
+complete -c cr -l dry-run -s d -f -d 'Dry run'
+complete -c cr -l force -s f -f -d 'Skip confirmations'
+complete -c cr -l keep-branch -s k -f -d 'Keep branches in cleanup'
+complete -c cr -l branch-only -s b -f -d 'Branch-only mode' \
+    -a '(__fish_cr_ticket_ids)'
+complete -c cr -l cleanup-branches-only -f -d 'Branches-only cleanup'
+complete -c cr -f -a cleanup -d 'Cleanup mode' \
+    -n 'not __fish_seen_subcommand_from cleanup'
+complete -c cr -n '__fish_seen_subcommand_from cleanup' -f \
+    -a '(__fish_cr_cleanup_branches)' -d 'cr-* branch'
+complete -c cr -n '__fish_seen_subcommand_from cleanup' -f
+complete -c cr -n 'not __fish_seen_subcommand_from cleanup' -f \
+    -a '(__fish_cr_branches)' -d 'Source branch'
+
+function __fish_cr_cleanup_branches
+    git worktree list --porcelain | awk '/^worktree /{print $2}' | while read -l wt
+        set base (basename $wt)
+        if string match -r '^cr-.*' $base
+            echo $base
+        end
+    end
+end
+
+function __fish_cr_branches --description 'List remote branches'
+    set -l exclude_branches main master develop dev trunk
+    set -l branches (git ls-remote --heads $CR_DEFAULT_REMOTE | \
+        sed 's|.*refs/heads/||')
+    for b in $branches
+        set b (string trim -- $b)
+        if not contains -- $b $exclude_branches
+            echo $b
+        end
+    end
+end
+
+function __fish_cr_ticket_ids --description 'List ticket IDs from remote branches'
+    for b in (git ls-remote --heads $CR_DEFAULT_REMOTE | \
+        sed 's|.*refs/heads/||')
+        set b (string trim -- $b)
+        set -l id (string match -r '[0-9]+' -- $b)
+        if test -n "$id"
+            echo $id
+        end
+    end
+end

config/fish/functions/fzf_configure_bindings.fish

@@ -0,0 +1,46 @@
+# Always installs bindings for insert and default mode for simplicity and b/c it has almost no side-effect
+# https://gitter.im/fish-shell/fish-shell?at=60a55915ee77a74d685fa6b1
+function fzf_configure_bindings --description "Installs the default key bindings for fzf.fish with user overrides passed as options."
+    # no need to install bindings if not in interactive mode or running tests
+    status is-interactive || test "$CI" = true; or return
+
+    set -f options_spec h/help 'directory=?' 'git_log=?' 'git_status=?' 'history=?' 'processes=?' 'variables=?'
+    argparse --max-args=0 --ignore-unknown $options_spec -- $argv 2>/dev/null
+    if test $status -ne 0
+        echo "Invalid option or a positional argument was provided." >&2
+        _fzf_configure_bindings_help
+        return 22
+    else if set --query _flag_help
+        _fzf_configure_bindings_help
+        return
+    else
+        # Initialize with default key sequences and then override or disable them based on flags
+        # index 1 = directory, 2 = git_log, 3 = git_status, 4 = history, 5 = processes, 6 = variables
+        set -f key_sequences \e\cf \e\cl \e\cs \cr \e\cp \cv # \c = control, \e = escape
+        set --query _flag_directory && set key_sequences[1] "$_flag_directory"
+        set --query _flag_git_log && set key_sequences[2] "$_flag_git_log"
+        set --query _flag_git_status && set key_sequences[3] "$_flag_git_status"
+        set --query _flag_history && set key_sequences[4] "$_flag_history"
+        set --query _flag_processes && set key_sequences[5] "$_flag_processes"
+        set --query _flag_variables && set key_sequences[6] "$_flag_variables"
+
+        # If fzf bindings already exists, uninstall it first for a clean slate
+        if functions --query _fzf_uninstall_bindings
+            _fzf_uninstall_bindings
+        end
+
+        for mode in default insert
+            test -n $key_sequences[1] && bind --mode $mode $key_sequences[1] _fzf_search_directory
+            test -n $key_sequences[2] && bind --mode $mode $key_sequences[2] _fzf_search_git_log
+            test -n $key_sequences[3] && bind --mode $mode $key_sequences[3] _fzf_search_git_status
+            test -n $key_sequences[4] && bind --mode $mode $key_sequences[4] _fzf_search_history
+            test -n $key_sequences[5] && bind --mode $mode $key_sequences[5] _fzf_search_processes
+            test -n $key_sequences[6] && bind --mode $mode $key_sequences[6] "$_fzf_search_vars_command"
+        end
+
+        function _fzf_uninstall_bindings --inherit-variable key_sequences
+            bind --erase -- $key_sequences
+            bind --erase --mode insert -- $key_sequences
+        end
+    end
+end

config/git/ignore

@@ -21,3 +21,5 @@ dfm.sh
 .scannerwork
 .phpactor.json
 .zsh_history
+**/.claude/settings.local.json
+

config/git/shared

@@ -3,7 +3,7 @@
   helper = cache --timeout 30000
 
 [core]
-  excludesfile = ~/.config/git/gitignore
+  excludesfile = ~/.config/git/ignore
 
 [init]
   defaultBranch = main

config/nvim/lua/plugins/ui.lua

@@ -1,7 +1,22 @@
 return {
   {
-    'rmehri01/onenord.nvim',
+    'rose-pine/neovim',
-    opts = {},
+    name = 'rose-pine',
+    opts = {
+      dim_inactive_windows = false,
+      extend_background_behind_borders = true,
+      styles = {
+        bold = true,
+        italic = true,
+        transparency = true,
+      },
+      enable = {
+        terminal = true,
+        legacy_highlights = true, -- Improve compatibility for previous versions of Neovim
+        migrations = true, -- Handle deprecated options automatically
+      },
+    },
+    config = function() vim.cmd 'colorscheme rose-pine' end,
   },
   -- Automatic dark mode
   -- https://github.com/f-person/auto-dark-mode.nvim
@@ -12,10 +27,12 @@ return {
       set_dark_mode = function()
         vim.api.nvim_set_option_value('background', 'dark', {})
         -- vim.cmd.colorscheme(vim.g.colors_variant_dark)
+        vim.cmd 'colorscheme rose-pine'
       end,
       set_light_mode = function()
         vim.api.nvim_set_option_value('background', 'light', {})
         -- vim.cmd.colorscheme(vim.g.colors_variant_light)
+        vim.cmd 'colorscheme rose-pine-dawn'
       end,
     },
   },
@@ -68,6 +85,42 @@ return {
     'm4xshen/hardtime.nvim',
     lazy = false,
     dependencies = { 'MunifTanjim/nui.nvim' },
-    opts = {},
+    opts = {
+      restriction_mode = 'hint',
+      disabled_keys = {
+        ['<Up>'] = { '', 'n' },
+        ['<Down>'] = { '', 'n' },
+        ['<Left>'] = { '', 'n' },
+        ['<Right>'] = { '', 'n' },
+        ['<C-Up>'] = { '', 'n' },
+        ['<C-Down>'] = { '', 'n' },
+        ['<C-Left>'] = { '', 'n' },
+        ['<C-Right>'] = { '', 'n' },
+      },
+      disabled_filetypes = {
+        'TelescopePrompt',
+        'Trouble',
+        'lazy',
+        'mason',
+        'help',
+        'notify',
+        'dashboard',
+        'alpha',
+      },
+      hints = {
+        ['[dcyvV][ia][%(%)]'] = {
+          message = function(keys)
+            return 'Use ' .. keys:sub(1, 2) .. 'b instead of ' .. keys
+          end,
+          length = 3,
+        },
+        ['[dcyvV][ia][%{%}]'] = {
+          message = function(keys)
+            return 'Use ' .. keys:sub(1, 2) .. 'B instead of ' .. keys
+          end,
+          length = 3,
+        },
+      },
+    },
   },
 }

config/op/plugins.sh

@@ -1,2 +1,3 @@
+# shellcheck shell=bash
 export OP_PLUGIN_ALIASES_SOURCED=1
 alias gh="op plugin run -- gh"

config/shared.sh

@@ -26,7 +26,7 @@ x-path-prepend()
   local dir=$1
   case "$CURRENT_SHELL" in
     fish)
-      set -U fish_user_paths "$dir" $fish_user_paths
+      set -U fish_user_paths "$dir" "$fish_user_paths"
       ;;
     sh | bash | zsh)
       PATH="$dir:$PATH"
@@ -106,7 +106,7 @@ if ! declare -f msg_done > /dev/null; then
   # $1 - message (string)
   msg_done()
   {
-    msgr done "$1"
+    msgr "done" "$1"
     return 0
   }
 fi

config/yabai/yabairc

@@ -25,6 +25,7 @@ yabai -m config \
 # > yabai -m query --windows | jq .[].app | sort | uniq
 yabai -m rule --add app="1Password" manage=off
 yabai -m rule --add app="Fork" manage=off
+yabai -m rule --add app="GoLand" manage=off
 yabai -m rule --add app="JetBrains Rider" manage=off
 yabai -m rule --add app="Logi Options" manage=off
 yabai -m rule --add app="MSTeams" manage=off

config/zed/settings.json

@@ -1,6 +1,7 @@
 {
   "context_servers": {
     "github-activity-summarizer": {
+      "source": "extension",
       "settings": {}
     }
   },
@@ -8,12 +9,13 @@
     "metrics": false
   },
   "agent": {
-    "always_allow_tool_actions": false,
+    "always_allow_tool_actions": true,
+    "default_profile": "ask",
     "default_model": {
       "provider": "copilot_chat",
       "model": "gpt-4.1"
     },
-    "version": "2"
+    "play_sound_when_agent_done": true
   },
   "languages": {
     "PHP": {
@@ -77,7 +79,7 @@
       "update_debounce_ms": 150
     }
   },
-  "multi_cursor_modifier": "cmd_or_ctrl", // alias: "cmd", "ctrl"
+  "multi_cursor_modifier": "cmd_or_ctrl",
   "indent_guides": {
     "enabled": true,
     "coloring": "indent_aware"
@@ -89,8 +91,8 @@
   "vim_mode": true,
   "theme": {
     "mode": "system",
-    "light": "Tomorrow",
+    "light": "Rosé Pine Dawn",
-    "dark": "Tomorrow at Midnight"
+    "dark": "Rosé Pine"
   },
   "inlay_hints": {
     "enabled": true,
@@ -102,7 +104,6 @@
   "buffer_font_size": 16,
   "buffer_font_fallbacks": ["JetBrainsMono Nerd Font"],
   "use_autoclose": false,
-  "hour_format": "hour24",
   "auto_install_extensions": {
     "angular": true,
     "ansible": true,
@@ -114,9 +115,9 @@
     "dockerfile": true,
     "git-firefly": true,
     "github-activity-summarizer": true,
+    "go-snippets": true,
     "golangci-lint": true,
     "gosum": true,
-    "go-snippets": true,
     "html": true,
     "ini": true,
     "json": true,
@@ -126,19 +127,20 @@
     "lua": true,
     "make": true,
     "php": true,
-    "python-snippets": true,
     "python-requirements": true,
+    "python-snippets": true,
+    "rose-pine-theme": true,
     "ruff": true,
     "scss": true,
     "sieve": true,
-    "stylelint": true,
     "sql": true,
+    "stylelint": true,
+    "templ": true,
     "toml": true,
     "vue": true,
     "vue-snippets": true,
     "wakatime": true,
     "xcode-themes": true,
-    "yaml": true,
+    "yaml": true
-    "tomorrow-theme": true
   }
 }

scripts/install-cargo-packages.sh

@@ -38,7 +38,7 @@ install_packages()
     if [[ ${pkg:0:1} == "#" ]]; then continue; fi
 
     msgr run "Installing cargo package $pkg"
-    cargo install --jobs $BUILD_JOBS "$pkg"
+    cargo install --jobs "$BUILD_JOBS" "$pkg"
     msgr run_done "Done installing $pkg"
     echo ""
   done
@@ -56,13 +56,13 @@ post_install_steps()
 
   msgr run "Removing cargo cache"
   cargo cache --autoclean
-  msgr done "Done removing cargo cache"
+  msgr "done" "Done removing cargo cache"
 }
 
 main()
 {
   install_packages
-  msgr done "Installed cargo packages!"
+  msgr "done" "Installed cargo packages!"
   post_install_steps
 }
 

scripts/install-ntfy.sh

@@ -9,7 +9,7 @@ VERBOSE="${VERBOSE:-0}"
 
 # Check if ntfy is already installed
 if x-have "ntfy"; then
-  msgr done "ntfy already installed"
+  msgr "done" "ntfy already installed"
   exit 0
 fi
 
@@ -50,7 +50,7 @@ install_ntfy()
 main()
 {
   install_ntfy
-  msgr done "ntfy installation complete"
+  msgr "done" "ntfy installation complete"
 }
 
 main "$@"